SKY外语计算机学习

标题: 程序开机运行 [打印本页]
作者: SKY定格    时间: 2012-5-14 19:45
标题: 程序开机运行
本帖最后由 sky_yx 于 2015-12-30 14:23 编辑

有两种方法，1是注册表方式
模块代码
  1. Option Explicit
  2. Public Declare Function RegSetValueEx Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, lpData As Any, ByVal cbData As Long) As Long
  3. Public Declare Function RegCreateKey Lib "advapi32.dll" Alias "RegCreateKeyA" (ByVal hKey As Long, ByVal lpSubKey As String, phkResult As Long) As Long
  4. Public Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long
  5. Public Declare Function RegDeleteValue Lib "advapi32.dll" Alias "RegDeleteValueA" (ByVal hKey As Long, ByVal lpValueName As String) As Long
  6. Public Const REG_SZ = 1
  7. Public Const HKEY_LOCAL_MACHINE = &H80000002
  8. '*************************************************************************
  9. '**函 数 名： SetAutoRun
  10. '**输    入： ByVal Autorun(Boolean) -
  11. '**输    出： 无
  12. '**功能描述： 随WINDOWS自动启动/取消启动模块
  13. '**全局变量：
  14. '**调用方法： Call SetAutoRun(True/False)
  15. '*************************************************************************
  16. Public Sub SetAutoRun(ByVal Autorun As Boolean)
  17.     Dim KeyId As Long
  18.     Dim MyexePath As String
  19.     Dim regkey As String
  20.    
  21.     MyexePath = App.Path & "\" & App.EXEName & ".exe" '获取程序位置
  22.     regkey = "Software\Microsoft\Windows\CurrentVersion\Run" '键值位置变量
  23.     Call RegCreateKey(HKEY_LOCAL_MACHINE, regkey, KeyId) '建立
  24.    
  25.     If Autorun Then
  26.         RegSetValueEx KeyId, "MySoftware", 0&, REG_SZ, ByVal MyexePath, LenB(MyexePath)
  27.     Else
  28.         RegDeleteValue KeyId, "MySoftware"
  29.     End If
  30.     RegCloseKey KeyId
  31. End Sub
  32. ‘调用方法
  33. SetAutoRun(ByVal Autorun As Boolean)
复制代码
2是利用Vb5stkit.dll里面的函数
窗体部分代码,加入6个按钮
  1. Option Explicit
  2. Private Sub CmdAddStartup_Click() '在开始菜单的启动程序组下创建记事本的快捷方式
  3. Call OSfCreateShellLink("\启动", "记事本", GetWindowsPath & "\Notepad.exe", "")
  4. End Sub
  5. Private Sub CmdAddDeskTop_Click() '在桌面创建记事本的快捷方式
  6. Call OSfCreateShellLink("..\..\桌面", "记事本", GetWindowsPath & "\Notepad.exe", "")
  7. End Sub
  8. Private Sub CmdAddProgram_Click() '在程序菜单的Notepad程序组下创建记事本的快捷方式
  9. Call OSfCreateShellGroup("Notepad") '先建立程序组
  10. Call OSfCreateShellLink("Notepad", "记事本", GetWindowsPath & "\Notepad.exe", "")
  11. End Sub
  12. Private Sub CmdAddStartMenu_Click()
  13. Dim i As Long
  14. For i = 1 To 5 '在开始菜单创建记事本的快捷方式,必须用循环才能创建?
  15. Call OSfCreateShellLink("..\..\「开始」菜单", "记事本", GetWindowsPath & "\Notepad.exe", "")
  16. Next
  17. End Sub
  18. Private Sub CmdQuickLaunch_Click() '在快捷工具栏下创建记事本的快捷方式
  19. Call OSfCreateShellLink("..\..\Application Data\Microsoft\Internet Explorer\Quick Launch", "记事本", GetWindowsPath & "\Notepad.exe", "")
  20. End Sub
  21. Private Sub CmdDelAllLink_Click()
  22. Call OSfRemoveShellLink("..\..\「开始」菜单", "记事本") '删除开始菜单上的快捷方式
  23. Call OSfRemoveShellLink("..\..\桌面", "记事本") '删除桌面上的快捷方式
  24. 'Call OSfRemoveShellLink("Notepad", "记事本") '删除Notepad程序组下的快捷方式,这样不能删除程序组
  25. Call RemoveShellGroup '删除Notepad程序组下的快捷方式
  26. Call OSfRemoveShellLink("\启动", "记事本") '删除启动菜单下的快捷方式
  27. Call OSfRemoveShellLink("..\..\Application Data\Microsoft\Internet Explorer\Quick Launch", "记事本") '删除快捷工具栏下的快捷方式
  28. End Sub
  29. Private Sub RemoveShellGroup()
  30. On Error GoTo ToExit '打开错误陷阱
  31. '------------------------------------------------
  32. 'RmDir删除一个存在的目录或文件夹。语法RmDir Path
  33. '必要的 path 参数是一个字符串表达式，用来指定要删除的目录或文件夹。path 可以包含驱动器。如果没有指定驱动器，则 RmDir 会在当前驱动器上删除目录或文件夹。
  34. '说明如果想要使用 RmDir 来删除一个含有文件的目录或文件夹，则会发生错误。在试图删除目录或文件夹之前，先使用 Kill 语句来删除所有文件。
  35. Kill (GetProgarmPath(Me.hWnd) & "\Notepad\记事本.lnk")
  36. RmDir (GetProgarmPath(Me.hWnd) & "\Notepad")
  37. '------------------------------------------------
  38. Exit Sub
  39. '----------------
  40. ToExit:
  41. Resume Next
  42. End Sub
  43. ’模块代码
  44. Option Explicit
  45. '-----------------------------------------------------
  46. '               创建和删除快捷方式
  47. '-----------------------------------------------------
  48. '               洪恩在线  求知无限
  49. '-----------------------------------------------------
  50. '------名称-------------------作用--------------------
  51. '       CmdAddStartup             "创建启动程序组快捷方式"
  52. '       CmdAddDeskTop             "创建桌面快捷方式"
  53. '       CmdAddStartMenu           "创建开始菜单快捷方式"
  54. '       CmdAddProgram             "创建程序组下的快捷方式"
  55. '       CmdQuickLaunch            "创建快捷工具栏的快捷方式"
  56. '       CmdDelAllLink             "删除所有快捷方式"
  57. '-----------------------------------------------------
  58. '要在VB中创建Windows的快捷方式，需要用到VB的一个动态链接库
  59. 'Vb5stkit.dll。在该动态链接库中提供了三个函数
  60. 'OSfCreateShellGroup、OSfCreateShellLink、OSfRemoveShellLink
  61. '分别用于创建快捷方式程序组、创建快捷方式和删除快捷方式。
  62. '-----------------------------------------------------
  63. Declare Function OSfCreateShellGroup Lib "Vb5stkit.dll" _
  64.         Alias "fCreateShellFolder" (ByVal lpstrDirName As String) As Long
  65.         
  66. 'lpstrDirName指定了程序组的名称
  67. '-----------------------------------------------------
  68. Declare Function OSfCreateShellLink Lib "Vb5stkit.dll" _
  69.         Alias "fCreateShellLink" (ByVal lpstrFolderName As String, _
  70.         ByVal lpstrLinkName As String, ByVal lpstrLinkPath As String, ByVal lpstrLinkArguments As String) As Long
  71.         
  72. 'lpstrfoldername指定保存快捷方式的文件夹
  73. 'lpstrlinkname指定快捷方式的文件名
  74. 'lpstrLinkpathe指定快捷方式所指向的应用程序或文件
  75. 'lpstrLinkArguments是程序运行所需的参数
  76. '-----------------------------------------------------
  77. Declare Function OSfRemoveShellLink Lib "Vb5stkit.dll" Alias _
  78.         "fRemoveShellLink" (ByVal lpstrFolderName As String, ByVal lpstrLinkName As String) As Long
  79. '获取Windows目录
  80. Private Declare Function GetWindowsDirectory Lib "kernel32" Alias _
  81.                           "GetWindowsDirectoryA" (ByVal lpBuffer As String, ByVal nSize As Long) As Long
  82. '获得文件夹路径
  83. Private Declare Function SHGetSpecialFolderPath Lib "shell32.dll" Alias "SHGetSpecialFolderPathA" (ByVal hwndOwner As Long, ByVal lpszPath As String, ByVal nFolder As Long, ByVal fCreate As Long) As Long
  84. Private Const Max_Path = 260       '缓冲区大小
  85. Private Const CSIDL_PROGRAMS = &H2 '程序组常量
  86. '*************************************************************************
  87. '**函 数 名： GetWindowsPath
  88. '**输    入： 无
  89. '**输    出： (String) -
  90. '**功能描述： 得到Windows路径
  91. '**全局变量：
  92. '**调用模块：
  93. '*************************************************************************
  94. Public Function GetWindowsPath() As String
  95.     Dim ChrLen As Long, WinDir As String
  96.     WinDir = Space$(Max_Path)
  97.     ChrLen = GetWindowsDirectory(WinDir, Max_Path)
  98.     WinDir = Left$(WinDir, ChrLen)
  99.     GetWindowsPath = WinDir
  100. End Function
  101. '*************************************************************************
  102. '**函 数 名： GetProgarmPath
  103. '**输    入： frmHwnd(Long) -
  104. '**输    出： (String) -
  105. '**功能描述： 获取开始菜单程序组的路径
  106. '**全局变量：
  107. '**调用模块：
  108. '*************************************************************************
  109. Public Function GetProgarmPath(frmHwnd As Long) As String
  110.     Dim CSILD_NUM As Long, strBouff As String
  111.     strBouff = String$(Max_Path, 0)
  112.     SHGetSpecialFolderPath frmHwnd, strBouff, CSIDL_PROGRAMS, 0
  113.     GetProgarmPath = Left$(strBouff, InStr(1, strBouff, Chr$(0)) - 1)
  114. End Function
复制代码
方法三 先引用系统里面都有的WSHom.Ocx
  1. Option Explicit
  2. '*************************************************************************
  3. '**函 数 名： SetAutoRun
  4. '**输    入： ByVal Autorun(Boolean) -
  5. '**输    出： 无
  6. '**功能描述： 随WINDOWS自动启动/取消启动模块
  7. '**全局变量：
  8. '**调用方法： Call SetAutoRun(True/False)
  9. '*************************************************************************
  10. Public Sub SetAutoRun(ByVal Autorun As Boolean)
  11.    
  12.     'WshShell 对象
  13.     'ProgId Wscript.Shell
  14.     '文件名 WSHom.Ocx
  15.    
  16.     Dim WshShell As WshShell
  17.    
  18.     Set WshShell = CreateObject("Wscript.Shell")
  19.    
  20.     If Autorun Then
  21.         WshShell.RegWrite "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\" & App.EXEName, App.Path & "\" & App.EXEName & ".exe"
  22.     Else
  23.         WshShell.RegDelete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\" & App.EXEName
  24.     End If
  25.    
  26.     Set WshShell = Nothing
  27.    
  28. End Sub
复制代码






欢迎光临 SKY外语计算机学习 (http://skywj.com/) Powered by Discuz! X2.5